Een recordset weergeven
De inhoud van een recordset weergeven kan op meerdere manieren. De makkelijkste en meest
gebruikte manier is door de recordset heen bladeren en stuk voor stuk de records naar de
browser schrijven. Door de manier waarop ADO met databases om gaat, is dit echter niet
de meest efficiënte methode. Een voor ASP betere (snellere) methode is alle records in
een array schrijven met een speciaal daarvoor gemaakte functie:
GetRows.
Omdat het belangrijk is dat je meteen de goede methode leert, geven we daarvan een
voorbeeld. Wil je meer informatie hierover lees dan
Data ophalen met GetRows.
In het onderstaande voorbeeld openen we een database, halen we de gegevens op met
GetRows en geven we vervolgens de gegevens weer in een HTML-tabel.
select.asp
<%
Option Explicit
Dim objConn
Dim objRs
Dim arrRs
Dim strSQL
Dim lngVelden
Dim lngRecords
Dim i, j
strSQL = "SELECT CompanyName, Address, PostalCode, City, Country FROM Customers""
Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open Application("ConnString")
Set objRs = Server.CreateObject("ADODB.Recordset")
objRs.Open strSQL, objConn, adOpenForwardOnly, adLockReadOnly
If Not objRs.EOF Then
arrRs = objRs.GetRows()
lngVelden = UBound(arrRs)
lngRecords = UBound(arrRs, 2)
Else
lngRecords = -1
End If
objRs.Close
Set objRs = Nothing
objConn.Close
Set objConn = Nothing
%>
<HTML>
<BODY>
<TABLE BORDER="1">
<%
For i = 0 To lngRecords
Response.Write "<TR>"
For j = 0 To lngVelden
Response.Write "<TD>" & arrRs(j, i) & "</TD>"
Next
Response.Write "</TR>"
Next
%>
</TABLE>
</BODY>
</HTML>
|
